内容紹介

RDF化したデータは SparqlEPCUにあります。 (プロジェクト名：udct 意欲的な取組情報)
(SPARQLエンドポイント: http://lodcu.cs.chubu.ac.jp/SparqlEPCU/RDFServer.jsp?reqtype=api&project=attackInfo )

SPARQLのクエリーは以下の通り。

BASE    <http://example.org/lodChallenge2013/udct-data.aigid.jp/>
PREFIX :  <attackInfo#>
PREFIX p: <property#>
SELECT DISTINCT ?title ?start ?description ?lat ?long ?source ?sourceurl ?image
WHERE {
  ?s a  :取組型 ;
     p:カテゴリコード ?code ;    # 1:下水道，7:鉄道
     p:カテゴリ ?category ;
     rdfs:label  ?title ;
     p:説明 ?desc ;
     p:参照 ?sourceurl ;
     p:写真 ?image ;
     geo:lat  ?lat  ;
     geo:long  ?long .
  BIND(now() AS ?start)     # 日付データは現在とする
  OPTIONAL{
    ?s  p:部門  ?bumon .
  }
  BIND(
    IF(bound(?bumon),
       concat("部門：",?bumon,"<br/>説明：",?desc),
       concat("説明：",?desc)
    ) AS ?desc2 
  ) 
  BIND(concat("カテゴリー：",?category,"(",?code,") <br/>",?desc2)
       AS ?description )
  BIND(if(contains(str(?sourceurl),"http://ja.wikipedia.org/wiki/"),
          "<br/>ウィキペディアで見る",
          "<br/>Webページを見る")
       AS ?source) 
}

カテゴリーコードは，1が下水道，7が鉄道です。カテゴリが鉄道の場合には，部門はありません。

なお，時間の情報はあまり意味を持っていません。ここでは現在を示していますが，何を時間指定とすべきかは不明です。

カテゴリが鉄道の場合に部門はないため，?bumonはオプショナルな扱いとし，概要記述のところで，?bumon がバインドされているかを問うています。

下水道の取り組みでは，該当するホームページへのリンクを付けてみました。また鉄道の取り組みについてはウィキペディアの該当ページにリンクを付けてみました。写真は，リンク先のページのものを引用しています。

SPARQL TimeLinerで直接見るには，ここを参照してください。

UDCT 意欲的な取組情報(下水道，鉄道)

内容紹介