気象庁防災情報XML：配信feed情報

「AITC」が公開する 気象庁防災情報XML：配信feed情報 を利用して SPARQL Timelinerで可視化しました。

最近のデータのみに限定しています。 下のSPARQL Timelinerでの時刻表示では，2014年2月20日零時過ぎにSPARQL Timelinerを実行したので， 世界標準時の2月19日の値が示されています。日時には注意が必要ですね。

内容紹介

(SPARQLエンドポイント: http://api.aitc.jp/ds/sparql )

SPARQLのクエリーは 以下の通り。

# EndPoint: http://api.aitc.jp/ds/sparql
# 気象庁防災情報XML：配信feed情報
PREFIX xsd:   <http://www.w3.org/2001/XMLSchema#>
PREFIX atom: <http://www.w3.org/2005/Atom#>
PREFIX link2: <http://cloud.projectla.jp/jma/link2/>
SELECT DISTINCT ?title ?start ?description ?lat ?long ?source
WHERE{
    ?entry a atom:entry .
    ?entry atom:title ?atomTitle . # 竜巻注意情報，全般台風情報，府県天気概況 等
    ?entry atom:updated ?start .
    FILTER(
           year(xsd:dateTime(?start)) = year(now())
           &&  month(xsd:dateTime(?start)) = month(now())
           &&  day(xsd:dateTime(?start)) >= day(now())-2
          )
    ?entry atom:author ?author .
    ?entry atom:link ?気象XML .
    ?author link2:name ?authorName .
    ?entry atom:content ?content .
    ?author link2:location [link2:lat ?緯度; link2:lng ?経度] .
    BIND(concat(strafter(?content,'】')) AS ?テキスト)
    BIND(concat(?atomTitle,' <br/>【',?authorName,' 】') AS ?種類【気象台】)
    FILTER(?テキスト != '')
    BIND(concat(?テキスト,'<br/>',str(?start)) AS ?description)
    BIND(?種類【気象台】 AS ?title)
    BIND(?緯度 AS ?lat)
    BIND(?経度 AS ?long)
    BIND(?気象XML AS ?source)
}
ORDER BY DESC(?start)
LIMIT 30

気象庁防災情報XMLを配信するfeed情報の各エントリーには，発信日時，気象台の情報，情報の種類，配信XMLの情報があります。 位置情報は，気象台の位置情報を基にしています。

各エントリーのタイトルは，竜巻注意情報，全般台風情報，府県天気概況等があります。 この値でエントリーをフィルターすると，SPARQL Timelinerで直接実行する場合の応答時間が早くなります。

時間の情報は，各気象台が発信する時刻を利用しています。 SPARQL Timelinerでの時刻表示は，世界標準時で表現されていますので， テキスト内での表現(日本時間)とは異なりますので注意してください。 ちなみに，日本時間の2014年2月20日零時過ぎの情報が表示されているはずです。

写真の情報はありません。

SPARQL TimeLinerで直接見るには， ここを参照してください。

直接SPARQLサーバーにクエリーするフォーム

「AITC」が公開する 気象庁防災情報XML：配信feed情報 を利用して，気象庁防災情報XMLの配信feed情報サーバーに対して，SPARQLクエリーを試す事ができます。

下のフォーム内にクエリーを入力し，「SPARQLクエリーの実行」ボタンをクリックすることで， 別タブで応答結果を見る事ができます。
SPARQLエンドポイントは， http://api.aitc.jp/ds/sparql です。

上のフォームでは，配信Feedのエントリータイトルを一覧するクエリーが予め設定されています。 「SPARQLクエリーの実行」ボタンをクリックすると，別タブでエントリータイトルの一覧が表示されます。

例えば，最初の例で示したクエリーをコピー・ペーストして，入力領域を変更し， 「SPARQLクエリーの実行」ボタンをクリックしてみてください。 応答にかなり時間を要しますが，どんなデータが送られてくるかをみる事ができます。 この場合，クリック時点で最新の情報が表示されます。