内容紹介

RDF化したデータは SparqlEPCUにあります。 (プロジェクト名：国民体育大会情報 (第45回~第68回))
(SPARQLエンドポイント: http://lodcu.cs.chubu.ac.jp/SparqlEPCU/RDFServer.jsp?reqtype=api&project=kokutaihaiInfo )

SPARQLのクエリーは以下の通り。

PREFIX : <http://example.org/lodChallenge2013/kokutaiInfo#>
PREFIX p: <http://example.org/lodChallenge2013/property#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>
SELECT DISTINCT  ?title ?start ?image ?lat ?long ?description ?source ?sourceurl
WHERE {
  ?s  a  :国体型 .
  ?s  rdfs:label  ?label  .   
  ?s  p:回  ?nbr .
  ?s  p:年  ?year .
  ?s  p:大会名  ?taikaimei .
  ?s  p:スローガン  ?slogan .
  ?s  p:マスコット  ?mascot .
  ?s  p:マスコットurl ?image2 .
  ?s  p:開会宣言  ?sengen .
  ?s  p:選手宣誓  ?sensei .
  ?s  p:最終炬火ランナー  ?seika .
  ?s  p:主競技場  ?kyougijou .
  ?s  p:wiki参照  ?wikiurl .
  OPTIONAL {
  ?s  p:写真 [
          a  :写真型 ;
          geo:lat  ?lat ;
          geo:long  ?long ;
          p:開設  ?kaisetsu ;
          p:種類  "競技場" ;
          p:キャプション  ?cap ;
          p:url  ?image
      ] .
  }
  OPTIONAL {
  ?s  p:天皇杯成績 [
        p:都道府県 [
            a  :都道府県順位型 ;
            p:順位  1 ;
            p:総得点  ?point1 ;
            rdfs:label  ?rank1
        ]
      ] .
  ?s  p:天皇杯成績 [
        p:都道府県 [
            a  :都道府県順位型 ;
            p:順位  2 ;
            p:総得点  ?point2 ;
            rdfs:label  ?rank2
        ]
      ] .
  ?s  p:天皇杯成績 [
        p:都道府県 [
            a  :都道府県順位型 ;
            p:順位  3 ;
            p:総得点  ?point3 ;
            rdfs:label  ?rank3
        ]
      ] .
  }
 BIND(?year AS ?start)
 BIND(concat("第",str(?nbr),"回(",str(?year),"年)",'<br/>',?taikaimei) AS ?title)
 BIND(
      concat(
          "<span title='愛称，スローガン'>", ?slogan,"</span>",
          "<br/>天皇杯成績",
          "<br/> 優勝:", ?rank1, " (", str(?point1), ")",
          "<br/> 第2位:",?rank2," (", str(?point2), ")",
          "<br/> 第3位:",?rank3," (", str(?point3), ")",
          "<br/><span title='写真の説明'>写真:", ?cap,"</span>"
      ) AS ?description
 )
 BIND(concat("マスコット：",?mascot) AS ?source)
 BIND(?image2 AS ?sourceurl)
}ORDER BY  DESC(?start)

写真が提供されていない大会(1995年)があるため，p:写真をプロパティーに持つ場合には，OPTIONALで囲んでいます。また，天皇杯成績の情報もデータが抜けている部分があるため，OPTIONALとしています。

なお，時間の情報は大会の開催時期(p:年)にしています。競技場の開設年(p:開設)でも良いかもしれません。

幾つかの情報は，SPARQLクエリー式では記述されていますが，表示出力に関与しないものもあります。これらの属性は指定しなくても良いのですが，ここではこの様な属性もあるとのことを示すためにわざと記述しています。適宜変えて表示させてもいいですね。例えば，開会宣言，選手宣誓，最終炬火ランナー等。 p:wiki参照の属性を使って，wikiのページにリンク付けするのもいいかもしれません。皇后杯成績の情報はデータとしては持っていますが，クエリー式には入れていません。天皇杯成績と同様な三つ組み構造をしているので，試してみてください。

「国民体育大会情報 (第45回~第68回)」の三つ組みの構造は，この資料を参照してください。このWebアプリに関連したアイデア，データセット，アプリを紹介しています。私のPCでは，何故かFirefoxで表紙タイトルの漢字が抜けた状態になります。 LODチャレンジ2013に応募(アイデア，データセット，アプリケーション部門)したときの参考資料として作成した資料です。

写真の情報は現在は主競技場を基にしていますが，実際の競技の写真等で再利用が可能なものが用意されれば，より興味深いアプリになるでしょう。更にホームページへのリンク等の情報と連携できるとよりもっと良くなりますね。

SPARQL TimeLinerで直接見る場合には，ここを参照してください。

国民体育大会情報 (第45回～第68回)

内容紹介